Massless On-shell Double Box

(* Time of evaluation and the version of the Mathematica kernel used *)

DateString[]

$Version

Derivation of MB representation

(* On the basis of http://prac.us.edu.pl/~gluza/ambre/examples/example7.nb *)

<<MB.m

<<AMBREv1.2.m

(* barnesroutines.m by David A.Kosower, https://mbtools.hepforge.org/ *)

<<barnesroutines.m

m=0

B1=Fullintegral[
{1},
{PR[k1,m,n1]PR[k1+p1,0,n2]PR[k1+p1+p2,m,n3]PR[k1-k2,0,n4]PR[k2,m,n5]PR[k2+p1+p2,m,n6]PR[k2-p3,0,n7]},{k2,k1}];

invariants={p1^2->m^2,p2^2->m^2,p3^2->m^2,p4^2->m^2,p1*p2->1/2*s-m^2,p3*p4->1/2 s-m^2,p1*p3->1/2*t-m^2,p2*p4->1/2*t-m^2,p2*p3->1/2*u-m^2,p1*p4->1/2*u-m^2}/.u->4 m^2-s-t//Expand;

IntPart[1]

SubLoop[integral]

IntPart[2]

repr=SubLoop[integral];

BarnesLemma[repr,1]

fin=%/.{n1->1,n2->1,n3->1,n4->1,n5->1,n6->1,n7->1}

Kfin=fin*(-s)^(2+2*eps)*(-t)

Kfin=Kfin/.(((-s))^(2+2 eps+z3+z4)) (((-t))^(-3-2 eps-z3-z4)) t->-(((t/s))^(-(2+2 eps+z3+z4)))

Kfin=Kfin/.t/s->x

rules=MBoptimizedRules[Kfin,eps->0,{},{eps}]

integrals=MBcontinue[Kfin,eps->0,rules,Verbose->False];

ser=MBexpand[{integrals},Exp[2*eps EulerGamma],
{eps,0,0}]//MBmerge

Kmb=DoAllBarnes[ser,True]//MBmerge

(* Numerical check with V.A.Smirnov hep-ph/9905323 Eqs. 22-25 *)

Li[n_,z_]:=PolyLog[n,z]
S[a_,b_,z_]:=PolyLog[a,b,z]

K0t[x_]:=-4/eps^4+5Log[x]/eps^3-(2Log[x]^2-(5/2)Pi^2)/eps^2-
((2/3)Log[x]^3+11/2Pi^2Log[x]-65/3Zeta[3])/eps +4/3Log[x]^4+6Pi^2Log[x]^2-88/3Zeta[3]Log[x]+29/30Pi^4

K1t[x_]:=-(2Li[3,-x]-2Log[x]Li[2,-x]-(Log[x]^2+Pi^2)Log[1+x])*2/eps-
4(S[2,2,-x]-Log[x]S[1,2,-x])+44Li[4,-x]-4(Log[1+x]+6Log[x])Li[3,-x]+
2(Log[x]^2+2Log[x]Log[1+x]+10/3Pi^2)Li[2,-x]+
(Log[x]^2+Pi^2)Log[1+x]^2 -2/3(4Log[x]^3+5Pi^2Log[x]-6Zeta[3])Log[1+x]

K[x_]:=K0t[x]+K1t[x]

K1=MBintegrate[Kmb,{x->1/5},Complex->True]

K2=K[1/5]//N

K1[[1]]-K2